home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / gnustuff / tos / updates / update16.zoo / lib / bcopy.s next >
Encoding:
Text File  |  1992-03-06  |  2.8 KB  |  149 lines
  1. #APP
  2.  
  3. | void bcopy(void *src, void *dst, size_t cnt)
  4. |    handle overlap (both ways), odd/even alignment etc
  5. |    ++jrb    bammi@dsrgsun.ces.cwru.edu
  6. |
  7. |    modified to use, whenever possible, unrolled loops
  8. |    in both copy directions;
  9. |       no check for an overlap anymore, but copying goes
  10. |    up or down, depending on src-dst ordering;
  11. |    all loops recoded as (double) dbra loops;
  12. |    added entry point for 
  13. | void *memmove(void *dest, const void *src, size_t cnt);
  14. |    Michal Jaegermann ntomczak@vm.ucs.ualberta.ca
  15. |
  16. | 
  17.     .text
  18.     .even
  19.     .globl _bcopy
  20.     .globl _lbcopy
  21.     .globl _memmove
  22. _memmove:
  23.     movl    sp@(4),a1    | dst -> a1
  24.     movl    sp@(8),a0    | src -> a0
  25.     jra    L0
  26.  
  27. _bcopy:
  28. _lbcopy:
  29.     movl    sp@(4),a0    | src -> a0
  30.     movl    sp@(8),a1    | dst -> a1
  31. L0:
  32.     movl    sp@(12),d0    | cnt -> d0
  33.     jeq    return        | cnt == 0, nothing to do
  34.     cmpl    a1,a0        | which way to copy
  35.     jeq    return        | same source and destination? we are done
  36.     moveml    d2-d4/a1,sp@-    | save d2,d3,d4,a1(dst) - condition codes
  37.                 | are not affected
  38.     smi    d4        | d4 is set if we are going to copy down
  39.     jpl    L1
  40.     addl    d0,a0
  41.     addl    d0,a1
  42.  
  43. L1:
  44.     | check for odd src or dst
  45.     movw    a0,d1
  46.     movw    a1,d2
  47.     eorb    d1,d2
  48.     btst    #0,d2
  49.     jne    oddeven
  50.     btst    #0,d1        | do we have an extra byte?
  51.     jeq    setup
  52.     btst    #0,d4
  53.     jeq    upbyte
  54.     movb    a0@-,a1@-
  55.     jra    decrease
  56. upbyte:
  57.     movb    a0@+,a1@+
  58. decrease:
  59.     subql   #1,d0           | now even even
  60.  
  61. setup:
  62.     | if we are here we can unroll a copy loop
  63.     movl    d0,d2
  64.     lsrl    #5,d2        | how many times through a copy loop
  65.     movl    d2,d3        | get upper 16 bits of d2 into 
  66.     swap    d3        | lower word of d3
  67.  
  68.     | calculate loop offset - it has to be word anyway
  69.     movw    d0,d1
  70.     andw    #0x1c,d1    | 4 bytes/copy  32 bytes max/iter
  71.     lsrw    #1,d1        | calc index into loop (each movl == 2bytes)
  72.     negw    d1        |  
  73.     addw    #18,d1        | 16 + 2 bytes for jmp ext word - d1 == index
  74.  
  75.     btst    #0,d4
  76.     jeq    eveneven
  77.                 | drop into another loop to copy down
  78.     addw    #(loop2 - loop1),d1
  79.  
  80. eveneven:            | may want long alignment for 020/030 etc
  81.     jmp    pc@(0,d1:w)    | dive into a proper loop at appro spot
  82. loop1:
  83.     movl    a0@+,a1@+
  84.     movl    a0@+,a1@+
  85.     movl    a0@+,a1@+
  86.     movl    a0@+,a1@+
  87.  
  88.     movl    a0@+,a1@+
  89.     movl    a0@+,a1@+
  90.     movl    a0@+,a1@+
  91.     movl    a0@+,a1@+
  92.  
  93.     dbra    d2,loop1
  94.     dbra    d3,loop1
  95.  
  96.     btst    #1,d0
  97.     jeq    L4
  98.     movw    a0@+,a1@+    | residual word
  99. L4:    btst    #0,d0
  100.     jeq    ret
  101.     movb    a0@,a1@        | residual byte
  102. ret:
  103.     moveml    sp@+,d2-d4/a1
  104. return:
  105.     movl    a1,d0        | memmove returns its destination
  106.     rts
  107.  
  108. loop2:
  109.     movl    a0@-,a1@-
  110.     movl    a0@-,a1@-
  111.     movl    a0@-,a1@-
  112.     movl    a0@-,a1@-
  113.  
  114.     movl    a0@-,a1@-
  115.     movl    a0@-,a1@-
  116.     movl    a0@-,a1@-
  117.     movl    a0@-,a1@-
  118.  
  119.     dbra    d2,loop2
  120.     dbra    d3,loop2
  121.  
  122.     btst    #1,d0
  123.     jeq    L5
  124.     movw    a0@-,a1@-    | residual word
  125. L5:    btst    #0,d0
  126.     jeq    ret
  127.     movb    a0@-,a1@-    | residual byte
  128.     jra    ret
  129.     
  130. oddeven:
  131.     movl    d0,d1
  132.     swap    d1
  133.     btst    #0,d4
  134.     jne    downbra
  135.     jra    upbra
  136. upcopy:                | byte-by-byte forward
  137.     movb    a0@+,a1@+
  138. upbra:
  139.     dbra    d0,upcopy
  140.     dbra    d1,upcopy
  141.     jra    ret
  142.  
  143. downcopy:            | byte-by-byte backward
  144.     movb    a0@-,a1@-
  145. downbra:
  146.     dbra    d0,downcopy
  147.     dbra    d1,downcopy
  148.     jra    ret
  149.